home *** CD-ROM | disk | FTP | other *** search
/ LOGIC Apps / Logic-APPLE_II_APPS.iso / mac / LOGIC Apple II 5.25" Library - DOS Part 2 / DOS027.dsk / STARS.bas < prev    next >
BASIC Source File  |  2012-02-16  |  2KB  |  58 lines
  1. 70  HOME 
  2. 90  SPEED= 150
  3. 100  REM *** STARS *** STARS *** STARS*** STARS *** STARS ***
  4. 110  REM  *** PROGRAMMED BY K.G. WELK
  5. 120  PRINT "WELCOME TO MY GALAXY. I'M IN CHARGE OF THE STARS HERE"
  6. 130  PRINT "PLAY MY GAME *<CTRL-G>STARS<CTRL-G>*<CTRL-G> AND GET SOME STARS FOR YOURSELF!"
  7. 140  PRINT 
  8. 150  PRINT "WANT TO KNOW HOW TO PLAY ";
  9. 160  INPUT Z$
  10. 170  IF Z$ < >"Y"  THEN 280
  11. 180  REM  *** HERE IS HOW TO PLAY
  12. 190  PRINT 
  13. 200  PRINT "I WILL THINK OF A WHOLE NUMBER FROM 1 TO 100."
  14. 210  PRINT "TRY TO GUESS MY NUMBER. AFTER YOU GUESS, I"
  15. 220  PRINT "WILL TYPE ONE OR MORE STARS (*<CTRL-G>). THE CLOSER"
  16. 230  PRINT "YOU ARE TO MY NUMBER, THE MORE STARS (*<CTRL-G>) I WILL TYPE."
  17. 240  PRINT "ONE STAR (*<CTRL-G>) MEANS YOU ARE FAR AWAY FROM MY "
  18. 250  PRINT " NUMBER. SEVEN STARS (*******<CTRL-G><CTRL-G><CTRL-G><CTRL-G><CTRL-G><CTRL-G><CTRL-G>)MEANS YOU ARE VERY,"
  19. 260  PRINT "VERY, VERY CLOSE TO MY NUMBER!!!"
  20. 270  REM  *** COMPUTER 'THINKS' OF A NUMBER FROM 1 TO 100
  21. 280  LET X =  INT(100 * RND(1)) +1
  22. 290  PRINT 
  23. 300  PRINT "OK, STARSEEKER, I AM THINKING OF A NUMBER. START GUESSING."
  24. 310  REM  *** GUESSING BEGINS
  25. 320  LET N = 1
  26. 330  PRINT 
  27. 340  PRINT "WHAT IS YOUR GUESS?";
  28. 350  INPUT G
  29. 360  IF G = X  THEN 550
  30. 370  LET D =  ABS(G -X)
  31. 380  IF D > = 64  THEN 500
  32. 390  IF D > = 32  THEN 490
  33. 400  IF D > = 16  THEN 480
  34. 410  IF D > = 8  THEN 470
  35. 420  IF D > = 4  THEN 460
  36. 430  IF D > = 2  THEN 450
  37. 440  PRINT "*<CTRL-G>";
  38. 450  PRINT "*<CTRL-G>";
  39. 460  PRINT "*<CTRL-G>";
  40. 470  PRINT "*<CTRL-G>";
  41. 480  PRINT "*<CTRL-G>";
  42. 490  PRINT "*<CTRL-G>";
  43. 500  PRINT "*<CTRL-G>";
  44. 510  PRINT 
  45. 520  LET N = N +1
  46. 530  GOTO 330
  47. 540  REM  *** PLAYER HAS GUESSED THE GALACTIC NUMBER
  48. 550  FOR K = 1 TO 18
  49. 560  PRINT " **<CTRL-G><CTRL-G> ";
  50. 570  NEXT K
  51. 580  PRINT " !!! "
  52. 590  PRINT "THAT'S IT!!! YOU GUESSED MY COSMIC NUMBER IN ";N;" GUESSES."
  53. 600  PRINT 
  54. 610  PRINT "WANT TO PLAY AGAIN";
  55. 620  INPUT Z$
  56. 630  IF Z$ = "Y"  THEN 280
  57. 640  PRINT "OK, GOODBYE FOR NOW. PLAY WITH ME AGAIN SOMETIME."
  58. 650  END